data_resource = gnome.compile_resources(app_id + '.data',
	app_id + '.data.gresource.xml',
	source_dir: '.',
	gresource_bundle: true,
	install: true,
	install_dir : pkgdatadir
)

appsdir = join_paths(get_option('datadir'), 'applications')
desktop = intl.merge_file(
	input : app_id + '.desktop.in',
	output : app_id + '.desktop',
	po_dir : '../po',
	type : 'desktop',
	install: true,
	install_dir: appsdir
)

gsettingsdir = join_paths(get_option('datadir'), 'glib-2.0', 'schemas')
install_data(app_id + '.gschema.xml', install_dir : gsettingsdir)

appdatadir = join_paths(get_option('datadir'), 'appdata')
appdata = intl.merge_file(
	input : app_id + '.appdata.xml.in',
	output : app_id + '.appdata.xml',
	po_dir : '../po',
	type : 'xml',
	install: true,
	install_dir: appdatadir
)

install_data(
	app_id + '.png',
	install_dir : join_paths(get_option('datadir'), 'icons', 'hicolor', '512x512', 'apps')
)


install_data(
	app_id + '.svg',
	install_dir : join_paths(get_option('datadir'), 'icons', 'hicolor', 'scalable', 'apps')
)

servicedir = join_paths(get_option('datadir'), 'dbus-1', 'services')

service_conf = configuration_data()
service_conf.set('APP_ID', app_id)
service_conf.set('DATA_DIR', pkgdatadir)
service_conf.set('BIN_DIR', join_paths(get_option('prefix'), get_option('datadir'), app_id))

configure_file(
	input: '@0@.service.in'.format(app_id),
	output: '@0@.service'.format(app_id),
	configuration: service_conf,
	install: true,
	install_dir: servicedir
)